Special Aircraft Service

Please login or register.

Login with username, password and session length
Advanced search  
Pages: 1 2 [3] 4 5 6 ... 9   Go Down

Author Topic: B.A.T. V3.4 LINEBACKER  (Read 16784 times)

0 Members and 1 Guest are viewing this topic.

SAS~Storebror

  • Editor
  • member
  • Online Online
  • Posts: 16388
  • Ask me if I care.
    • Friendly Fire isn't.
Re: B.A.T. V3.4 LINEBACKER
« Reply #24 on: August 19, 2018, 11:42:49 PM »

Concerning false positives on the Installer:

We've had that discussion before, see e.g. here: https://www.sas1946.com/main/index.php/topic,53512.msg581997.html#msg581997
The installer is based on NSIS (Nullsoft Scriptable Install System), which unfortunately is prone to cause false positives on a small amount of AV programs, see here: http://nsis.sourceforge.net/NSIS_False_Positives

Changing the installer to another system like InstallShield or Inno Setup doesn't help much, as modern AV software like MS Defender will still treat the installer as "suspicious" at least, for the simple fact that it naturally isn't a "commonly seen" executable at the time of release.
You can trust me or you can trust independent 3rd party analyzers, for instance Virustotal, which holds the foodprint of our installer here (together with the only real false positive triggered on it):
https://www.virustotal.com/#/file/4267342d8a19cc839de1f162c80784d3b1ebd4dc37f55dafa7c1f4d104cd69ec

From that Virustotal list you can also see that in case your software is not McAfee based but still triggers an alert, then either the alert is just a warning (like it's the case for MS Defender) or your AV database needs an update (likely the case for Malwarebytes) or your AV settings are extremely pedantic and therefore cause false positives all over the place.

Fact is: The installer is safe.
This is the script behind - it's no secret -, anyone with NSIS installed (plus a few depency plugins, see script imports) can build the installer himself based on it:
Code: [Select]
; ****************************************************
; * This is the part you will be going to edit
; * if you want to change general settings, e.g.
; * the version number of BAT and/or the installer,
; * which will be shown on the installer screen
; * and which will set the installer filename
; *

!define OUTPUT_FILE_NAME "BAT 3.4 Linebacker Install.exe"
!define LOG_FILE_NAME "BAT 3.4 Linebacker Install.log"
!define PRODUCT_NAME "BAT 3.4 Linebacker"
!define PRODUCT_PUBLISHER "Hangar 19"
!define PRODUCT_WEB_SITE "http://www.sas1946.com"

; *
; ****************************************************

; ****************************************************
; * This defines the parts shipped with BAT
; * NUM_PARTS specifies the total number of BAT parts,
; * which will be used for showing up a correct
; * Progress Bar Value during installation
; * EXTRACTED_SIZE specifies how much space is
; * required when installing this pack
; *

!define NUM_PARTS '4'
!define EXTRACTED_SIZE '3343889'

; *
; * DISABLE_ALL_JSGME_OPTIONS when set to 'true' will
; * cause JSGME to deactivate all activated mods
; * prior to installing this pack.
; *

!define DISABLE_ALL_JSGME_OPTIONS "true"

; *
; * REMOVE_FILES defines files to be removed.
; * Removal will take place prior to installation,
; * after disabling JSGME options and before folders
; * will be deleted.
; * Each line consists of the filename (relative to
; * the BAT folder path) , followed by a colon and
; * a backslash. Wildcards are allowed for the
; * filename.
; *

!define REMOVE_FILES '\
'

; *
; * REMOVE_FILES_RECURSIVE defines files to be removed
; * from the installation folder and all it's subfolders
; * Removal will take place prior to installation,
; * after disabling JSGME options and before folders
; * will be deleted.
; * Each line consists of the filename (relative to
; * the BAT folder path) , followed by a colon and
; * a backslash. Wildcards are allowed for the
; * filename.
; *

!define REMOVE_FILES_RECURSIVE '\
'

; *
; * REMOVE_FOLDERS defines folders to be removed.
; * Removal will take place prior to installation,
; * after files have been deleted.
; * All files in the folders listed here will be
; * deleted automatically.
; * Each line consists of the foldername (relative
; * to the BAT folder path) , followed by a colon
; * and a backslash. Wildcards are NOT allowed.
; *

!define REMOVE_FOLDERS '\
#DOF3:\
#TGA3:\
#WAW3:\
#JTW3:\
BATMODS\\#BAT_00-CHAT-GB:\
BATMODS\\#BAT_00-CONT-DE-F:\
BATMODS\\#BAT_00-CONT-DE-M:\
BATMODS\\#BAT_00-CONT-GB-F:\
BATMODS\\#BAT_00-CONT-GB-M:\
BATMODS\\#WAW_00-AIRBOOST BOB:\
BATMODS\\#WAW_00_EngineMOD_2.7:\
BATMODS\\#WAW_00_PAL-ChocksMOD:\
BATMODS\\#DOF_BACKDROPS:\
BATMODS\\#JTW_BACKDROPS:\
BATMODS\\#JTW-ALT F-84F DORSAL01:\
BATMODS\\#JTW-ALT F-84F DORSAL02:\
BATMODS\\#JTW-ALT-IMPALA:\
BATMODS\\#JTW-ALT-J3CUB FLOATS:\
BATMODS\\#JTW-ALT-J3CUB TUNDRA:\
'

; *
; * RENAME_FILES defines files to be renamed.
; * Renaming will take place prior to installation,
; * after files have been deleted.
; * Each line consists of the old filename (relative
; * to the BAT folder path), followed by a colon,
; * followed by the new filename, followed by a colon
; * and a backslash. Wildcards are NOT allowed.
; *

!define RENAME_FILES '\
BAT01B\\DOF3DO.SFS:BAT01B\\DOF3DO01.SFS:\
BAT01B\\DOF3DO2.SFS:BAT01B\\DOF3DO02.SFS:\
BAT01B\\DOFSOUND.SFS:BAT01B\\DOFSOUND01.SFS:\
BAT02B\\TGA3DO.SFS:BAT02B\\TGA3DO01.SFS:\
BAT02B\\TGA3DO2.SFS:BAT02B\\TGA3DO02.SFS:\
BAT02B\\TGA3DO3.SFS:BAT02B\\TGA3DO03.SFS:\
BAT02B\\TGASOUND.SFS:BAT02B\\TGASOUND01.SFS:\
BAT03B\\WAW3DO.SFS:BAT03B\\WAW3DO01.SFS:\
BAT03B\\WAW3DO2.SFS:BAT03B\\WAW3DO02.SFS:\
BAT03B\\WAW3DO3.SFS:BAT03B\\WAW3DO03.SFS:\
BAT03B\\WAW3DO4.SFS:BAT03B\\WAW3DO04.SFS:\
BAT03B\\WAW3DO5.SFS:BAT03B\\WAW3DO05.SFS:\
BAT03B\\WAW3DO6.SFS:BAT03B\\WAW3DO06.SFS:\
BAT03B\\WAW3DO7.SFS:BAT03B\\WAW3DO07.SFS:\
BAT03B\\WAW3DO8.SFS:BAT03B\\WAW3DO08.SFS:\
BAT03B\\WAW3DO9.SFS:BAT03B\\WAW3DO09.SFS:\
BAT03B\\WAWSOUND.SFS:BAT03B\\WAWSOUND01.SFS:\
BAT04B\\JTW3DO.SFS:BAT04B\\JTW3DO01.SFS:\
BAT04B\\JTW3DO2.SFS:BAT04B\\JTW3DO02.SFS:\
BAT04B\\JTW3DO3.SFS:BAT04B\\JTW3DO03.SFS:\
BAT04B\\JTW3DO4.SFS:BAT04B\\JTW3DO04.SFS:\
BAT04B\\JTW3DO5.SFS:BAT04B\\JTW3DO05.SFS:\
BAT04B\\JTW3DO6.SFS:BAT04B\\JTW3DO06.SFS:\
BAT04B\\JTW3DO7.SFS:BAT04B\\JTW3DO07.SFS:\
BAT04B\\JTW3DO8.SFS:BAT04B\\JTW3DO08.SFS:\
BAT04B\\JTW3DO9.SFS:BAT04B\\JTW3DO09.SFS:\
BAT04B\\JTWSOUND.SFS:BAT04B\\JTWSOUND01.SFS:\
'

; *
; * BAT_PARTS defines the actual parts of BAT.
; * each line consists of the filename, followed by
; * a colon, then the hexadecimal CRC32 value of
; * that file, followed by another colon and
; * finally a backslash.
; *

!define BAT_PARTS '\
LINEBACKER_BAT01.zip:687a8a15:\
LINEBACKER_BAT02.zip:82a878b8:\
LINEBACKER_BAT03.zip:7cba8ea1:\
LINEBACKER_BAT04.zip:15eb1554:\
'

; *
; ****************************************************

; -+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+-+

; ****************************************************
; * Don't edit anything behind this line unless you
; * know exactly what you're doing!
; ****************************************************

; Use zlib compressor and don't use solid compression
; This is in order to cause as little false positives
; as possible...
SetCompressor /FINAL zlib

; Plugins
!include 'UMUI.nsh'
!include 'ZipDLL.nsh'
!include 'StdUtils.nsh'
!include 'LogicLib.nsh'
;!include 'FileFunc.nsh'

; Privilege Settings, no special privileges required
;RequestExecutionLevel user
RequestExecutionLevel admin

; Custom Settings
!define WELCOME_TITLE '      ${PRODUCT_NAME} \r\nBattlefield - Airborne - Tactical'
!define WELCOME_TEXT 'Setup will install\r\n\
\r\n\
${PRODUCT_NAME} \r\n\
Battlefield - Airborne - Tactical\r\n\
The Complete IL2 Supermod\r\n\
\r\n\
to your Computer.\r\n\
\r\n\
${PRODUCT_NAME} is to be installed on top of a working IL-2 1946 BAT game installation.\r\n\
When selecting the installation target directory, please enter your IL-2 1946 BAT game folder.\r\n\
\r\n\
Please click $\"Next$\" to continue!'

; MUI Settings
!define MUI_ABORTWARNING
!define MUI_ICON "Images\BAT.ico"
!define MUI_WELCOMEPAGE_TITLE '${WELCOME_TITLE}'
!define MUI_WELCOMEPAGE_TEXT '${WELCOME_TEXT}'

; UMUI Settings
!define UMUI_CUSTOMFUNCTION_GUIEND myguiend
!define UMUI_HEADERBGIMAGE_BMP "Images\BAT_Logo_NSIS_Header_UMUI_v2.bmp"
!define UMUI_LEFTIMAGE_BMP "Images\BAT_Logo_NSIS_v2.bmp"

; Branding
BrandingText "Hangar 19 - SAS - ${PRODUCT_NAME}"
Caption "·    ${PRODUCT_NAME}    ·    Installer    ·"

; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!define MUI_PAGE_HEADER_TEXT ""
!define MUI_PAGE_HEADER_SUBTEXT ""
!define MUI_LICENSEPAGE_TEXT_TOP "Please review the license file before installing $(^NameDA)."
!define MUI_LICENSEPAGE_TEXT_BOTTOM "Press Page Down to see the rest of the readme file.$\r$\n\
When you have finished reading, click on Next to start installing."
!insertmacro MUI_PAGE_LICENSE "BAT License.rtf"
; Directory page
!define MUI_PAGE_HEADER_TEXT ""
!define MUI_PAGE_HEADER_SUBTEXT ""
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!define MUI_PAGE_HEADER_TEXT ""
!define MUI_PAGE_HEADER_SUBTEXT ""
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!define MUI_PAGE_HEADER_TEXT ""
!define MUI_PAGE_HEADER_SUBTEXT ""
!insertmacro MUI_PAGE_FINISH

; Language files
!insertmacro MUI_LANGUAGE "English"

; MUI end ------


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;  Execute a command with cmd.exe
;;  P1 :in: Working directory (""=$outdir)
;;  P2 :in: Command and parameters
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
!define CmdNoWait "!insertmacro _CmdExec 0"         ; nopause/nowait
!define CmdWait "!insertmacro _CmdExec 1"      ; wait for end of execution
!define CmdPause "!insertmacro _CmdExec 2"     ; pause before exiting
!define CmdPauseWait "!insertmacro _CmdExec 3" ; pause + execwait
!define CmdStay "!insertmacro _CmdExec 4"       ; stay in command prompt
!define CmdStayWait  "!insertmacro _CmdExec 5"  ; stay + execwait
;;
!macro _CmdExec _Mode_ _WorkDir_ _CommandAndParams_
   Push $R0
   ExpandEnvStrings $R0 '%COMSPEC%'
   StrCmp "${_WorkDir_}" "" +3
      Push $OutDir
      SetOutPath "${_WorkDir_}"
   !if '${_Mode_}' == '2'
      Exec `"$R0" /c "${_CommandAndParams_}" & echo. & echo. & pause`
   !else if '${_Mode_}' == '1'
      ExecWait `"$R0" /c "${_CommandAndParams_}"`
   !else if '${_Mode_}' == '3'
      ExecWait `"$R0" /c "${_CommandAndParams_}" & echo. & echo. & pause`
   !else if '${_Mode_}' == '4'
      Exec `"$R0" /k "${_CommandAndParams_}"`
   !else if '${_Mode_}' == '5'
      ExecWait `"$R0" /k "${_CommandAndParams_}"`
   !else
      Exec `"$R0" /c "${_CommandAndParams_}"`
   !endif
   StrCmp "${_WorkDir_}" "" +3
      Pop $R0
      SetOutPath "$R0"
   Pop $R0
!macroend

Function myguiend
  RealProgress::Unload
FunctionEnd

Function StrTok
  Exch $R1
  Exch 1
  Exch $R0
  Push $R2
  Push $R3
  Push $R4
  Push $R5
 
  ;R0 fullstring
  ;R1 tokens
  ;R2 len of fullstring
  ;R3 len of tokens
  ;R4 char from string
  ;R5 testchar
 
  StrLen $R2 $R0
  IntOp $R2 $R2 + 1
 
  loop1:
    IntOp $R2 $R2 - 1
    IntCmp $R2 0 exit
 
    StrCpy $R4 $R0 1 -$R2
 
    StrLen $R3 $R1
    IntOp $R3 $R3 + 1
 
    loop2:
      IntOp $R3 $R3 - 1
      IntCmp $R3 0 loop1
 
      StrCpy $R5 $R1 1 -$R3
 
      StrCmp $R4 $R5 Found
    Goto loop2
  Goto loop1
 
  exit:
  ;Not found!!!
  StrCpy $R1 ""
  StrCpy $R0 ""
  Goto Cleanup
 
  Found:
  StrLen $R3 $R0
  IntOp $R3 $R3 - $R2
  StrCpy $R1 $R0 $R3
 
  IntOp $R2 $R2 - 1
  IntOp $R3 $R3 + 1
  StrCpy $R0 $R0 $R2 $R3
 
  Cleanup:
  Pop $R5
  Pop $R4
  Pop $R3
  Pop $R2
  Exch $R0
  Exch 1
  Exch $R1
 
FunctionEnd

;!define LVM_GETITEMCOUNT 0x1004
!define LVM_GETITEMTEXT 0x102D
 
Function DumpLog
  Exch $5
  Push $0
  Push $1
  Push $2
  Push $3
  Push $4
  Push $6
 
  SetDetailsPrint both
  DetailPrint "Creating Installer Logfile"
  FindWindow $0 "#32770" "" $HWNDPARENT
  GetDlgItem $0 $0 1016
  StrCmp $0 0 exit
  FileOpen $5 $5 "w"
  StrCmp $5 "" exit
    SendMessage $0 ${LVM_GETITEMCOUNT} 0 0 $6
    System::Alloc ${NSIS_MAX_STRLEN}
    Pop $3
    StrCpy $2 0
    System::Call "*(i, i, i, i, i, i, i, i, i) i \
      (0, 0, 0, 0, 0, r3, ${NSIS_MAX_STRLEN}) .r1"
    loop: StrCmp $2 $6 done
      System::Call "User32::SendMessageA(i, i, i, i) i \
        ($0, ${LVM_GETITEMTEXT}, $2, r1)"
      System::Call "*$3(&t${NSIS_MAX_STRLEN} .r4)"
      FileWrite $5 "$4$\r$\n"
      IntOp $2 $2 + 1
      Goto loop
    done:
      FileClose $5
      System::Free $1
      System::Free $3
  exit:
    Pop $6
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Pop $0
    Exch $5
FunctionEnd

Name "${PRODUCT_NAME}"
OutFile "${OUTPUT_FILE_NAME}"
InstallDir "$EXEDIR"
ShowInstDetails hide

Var BAT_ERROR
Var BAT_PART
Var BAT_PART_CHECK
Var FILE_CHECK
Var DAMAGED_FILES
Var CUR_PART
Var CUR_PERCENTAGE
Var CUR_FILE
Var NEW_FILE
Var CUR_FOLDER
Var COMSPEC
;Var TEMPVAR
;Var SKIPHASHERRORS

Section "BAT_CHECK" SEC01
  SetDetailsPrint both
  StrCpy $CUR_PART "0"
  RealProgress::SetProgress /NOUNLOAD 0
  StrCpy $DAMAGED_FILES ""
; StrCpy $SKIPHASHERRORS "FALSE"
; ${GetOptions} $CMDLINE "/nohasherrors" $TEMPVAR
; IfErrors +2
; StrCpy $SKIPHASHERRORS "TRUE"
Push ${BAT_PARTS}
${Do}
  Push ":"
Call StrTok
Pop $R0
StrCpy $BAT_PART $R0
  Push ":"
Call StrTok
Pop $R0
StrCpy $BAT_PART_CHECK $R0
${If} $BAT_PART != ""
  IntOp $CUR_PART $CUR_PART + 1
  IntOp $CUR_PERCENTAGE $CUR_PART * 25
  IntOp $CUR_PERCENTAGE $CUR_PERCENTAGE / ${NUM_PARTS}
      RealProgress::SetProgress /NOUNLOAD $CUR_PERCENTAGE
  DetailPrint "Checking File $BAT_PART"
  ${StdUtils.HashFile} $FILE_CHECK "CRC-32" "$EXEDIR\$BAT_PART"
  SetDetailsPrint listonly
;   ${If} $SKIPHASHERRORS == "TRUE"
;     DetailPrint "$BAT_PART Checksum is: $FILE_CHECK"
;   ${Else}
    ${If} $FILE_CHECK != $BAT_PART_CHECK
      StrCpy $DAMAGED_FILES "$DAMAGED_FILES$BAT_PART$\r$\n"
      DetailPrint "$BAT_PART is damaged!"
      DetailPrint "Checksum should be: $BAT_PART_CHECK"
      DetailPrint "Checksum is       : $FILE_CHECK"
    ${Else}
      DetailPrint "$BAT_PART is okay!"
    ${EndIf}
;   ${EndIf}
  SetDetailsPrint both
${EndIf}
${LoopUntil} $R0 == ""
Pop $R1
${If} $DAMAGED_FILES != ""
  DetailPrint "Errors occured, aborting installation!"
  StrCpy $0 "$EXEDIR\${LOG_FILE_NAME}"
Push $0
Call DumpLog
  MessageBox MB_ICONSTOP|MB_OK "The following files are damaged:$\r$\n$\r$\n$DAMAGED_FILES$BAT_PART$\r$\n$\r$\nAborting Installation!"
  Abort "BAT Files are damaged!"
${EndIf}
SectionEnd

Section "BAT_DISABLE_JSGME" SEC02
  RealProgress::SetProgress /NOUNLOAD 30
  ${If} ${DISABLE_ALL_JSGME_OPTIONS} == "true"
    DetailPrint "Disabling all active JSGME Options..."
    SetDetailsPrint none
    Push $OUTDIR
    SetOutPath $INSTDIR
    SetDetailsPrint both
    ExecWait '"$INSTDIR\JSGME.exe" /da /x'
    SetDetailsPrint none
    Pop $R0
    SetOutPath $R0
    SetDetailsPrint both
    DetailPrint "Disabling all active JSGME Options finished."
  ${EndIf}
SectionEnd

Section "BAT_REMOVE_FILES" SEC03
  RealProgress::SetProgress /NOUNLOAD 35
  ExpandEnvStrings $COMSPEC '%COMSPEC%'
Push "${REMOVE_FILES}"
  SetDetailsPrint both
${Do}
  Push ":"
Call StrTok
Pop $R0
StrCpy $CUR_FILE $R0
${If} $CUR_FILE != ""
  DetailPrint "Removing File $CUR_FILE"
;   SetDetailsPrint none
      nsExec::ExecToLog '"$COMSPEC" /C attrib -h -s -r "$INSTDIR\$CUR_FILE"'
      Pop $0
      nsExec::ExecToLog '"$COMSPEC" /C del /F /Q "$INSTDIR\$CUR_FILE"'
      Pop $0
;      SetDetailsPrint both
${EndIf}
${LoopUntil} $R0 == ""
SectionEnd

Section "BAT_REMOVE_FILES_RECURSIVE" SEC04
  RealProgress::SetProgress /NOUNLOAD 37
  ExpandEnvStrings $COMSPEC '%COMSPEC%'
Push "${REMOVE_FILES_RECURSIVE}"
  SetDetailsPrint both
${Do}
  Push ":"
Call StrTok
Pop $R0
StrCpy $CUR_FILE $R0
${If} $CUR_FILE != ""
  DetailPrint "Removing File (Recursive) $CUR_FILE"
;   SetDetailsPrint none
      nsExec::ExecToLog '"$COMSPEC" /C attrib -h -s -r "$INSTDIR\$CUR_FILE" /S'
      Pop $0
      nsExec::ExecToLog '"$COMSPEC" /C del /F /Q /S "$INSTDIR\$CUR_FILE"'
      Pop $0
;      SetDetailsPrint both
${EndIf}
${LoopUntil} $R0 == ""
SectionEnd

Section "BAT_REMOVE_FOLDERS" SEC05
  RealProgress::SetProgress /NOUNLOAD 40
  ExpandEnvStrings $COMSPEC '%COMSPEC%'
Push "${REMOVE_FOLDERS}"
  SetDetailsPrint both
${Do}
  Push ":"
Call StrTok
Pop $R0
StrCpy $CUR_FOLDER $R0
${If} $CUR_FOLDER != ""
  DetailPrint "Removing Folder $CUR_FOLDER"
;   SetDetailsPrint none
      nsExec::ExecToLog '"$COMSPEC" /C rmdir /Q /S "$INSTDIR\$CUR_FOLDER"'
      Pop $0
;      SetDetailsPrint both
${EndIf}
${LoopUntil} $R0 == ""
SectionEnd

Section "BAT_RENAME_FILES" SEC06
  RealProgress::SetProgress /NOUNLOAD 42
  ExpandEnvStrings $COMSPEC '%COMSPEC%'
Push "${RENAME_FILES}"
  SetDetailsPrint both
${Do}
  Push ":"
Call StrTok
Pop $R0
StrCpy $CUR_FILE $R0
  Push ":"
Call StrTok
Pop $R0
StrCpy $NEW_FILE $R0
${If} $CUR_FILE != ""
${If} $NEW_FILE != ""
  DetailPrint "Renaming $CUR_FILE to $NEW_FILE"
;   SetDetailsPrint none
      nsExec::ExecToLog '"$COMSPEC" /C move /Y "$INSTDIR\$CUR_FILE" "$INSTDIR\$NEW_FILE"'
      Pop $0
;      SetDetailsPrint both
${EndIf}
${EndIf}
${LoopUntil} $R0 == ""
SectionEnd

Section "BAT_INSTALL" SEC07
  SetDetailsPrint both
  StrCpy $CUR_PART "0"
  RealProgress::SetProgress /NOUNLOAD 45
  StrCpy $BAT_ERROR "false"
Push "${BAT_PARTS}"
${Do}
  Push ":"
Call StrTok
Pop $R0
StrCpy $BAT_PART $R0
  Push ":"
Call StrTok
Pop $R0
${If} $BAT_PART != ""
  IntOp $CUR_PART $CUR_PART + 1
  IntOp $CUR_PERCENTAGE $CUR_PART * 50
  IntOp $CUR_PERCENTAGE $CUR_PERCENTAGE / ${NUM_PARTS}
  IntOp $CUR_PERCENTAGE $CUR_PERCENTAGE + 45
      RealProgress::SetProgress /NOUNLOAD $CUR_PERCENTAGE
  DetailPrint "Installing File $BAT_PART"
  extractagain:
  SetDetailsPrint listonly
  !insertmacro ZIPDLL_EXTRACT "$EXEDIR\$BAT_PART" "$INSTDIR" "<ALL>"
SetDetailsPrint both
  Pop $0
  ;Sleep 100
  ;StrCpy $0 "success"
  ${If} $0 != "success"
        StrCpy $BAT_ERROR "true"
    SetDetailsPrint listonly
  DetailPrint "*****************************************************"
  DetailPrint "*** Error During Extraction of $BAT_PART !!!"
  DetailPrint "*** Error Message: $0"
  DetailPrint "*****************************************************"
  SetDetailsPrint both
  MessageBox MB_ICONEXCLAMATION|MB_ABORTRETRYIGNORE "Error During Extraction of $BAT_PART !!!$\r$\nError Message: $0" /SD IDIGNORE IDRETRY extractagain IDIGNORE extractignore
  StrCpy $R0 ""
  extractignore:
  ${Else}
    DetailPrint "$BAT_PART installed successfully."
  ${EndIf}
${EndIf}
${LoopUntil} $R0 == ""
RealProgress::SetProgress /NOUNLOAD 100
Pop $R1
${If} $BAT_ERROR == "true"
  DetailPrint "Errors occured, aborting installation!"
  StrCpy $0 "$EXEDIR\${LOG_FILE_NAME}"
Push $0
Call DumpLog
  MessageBox MB_ICONSTOP|MB_OK "Errors detected during installation!$\r$\n$\r$\nPlease check ${LOG_FILE_NAME} file contents!$\r$\n$\r$\nAborting Installation!"
  Abort "Error During BAT Installation!"
${EndIf}
SectionEnd

Section "-CleanUp"
  StrCpy $0 "$EXEDIR\${LOG_FILE_NAME}"
Push $0
Call DumpLog
SectionEnd

Function .onInit
   SectionSetSize ${SEC05} ${EXTRACTED_SIZE}
FunctionEnd

]cheers[
Mike
Logged
Learn. Challenge. Improve. In loving memory of the times when I cared...

EHood

  • Supporter
  • member
  • Offline Offline
  • Posts: 406
Re: B.A.T. V3.4 LINEBACKER
« Reply #25 on: August 20, 2018, 12:17:31 AM »

I, too, have been unable to start the installer. When I try, a red stripe of a window appears telling me that "This app can't run on your PC." According to a Windows Defender notification that pops up each time I download the installer, the virus in question is called Trojan:Win32/Fuery.8!cl

I have Malwarebytes as well, but this has no report of any sort of "event" for this date.

A friend advised that when I next attempt to install Linebacker, I should take my PC off line and de-activate Defender before I try to start the installer. This seems a bit drastic. Does anyone out there have a better idea? (it's very frustrating, having all of the necessary parts for Linebacker, but not having a way to install them.)

Logged
Etiam necesso campanum vaccis!

GEORGES44

  • member
  • Offline Offline
  • Posts: 130
Re: B.A.T. V3.4 LINEBACKER
« Reply #26 on: August 20, 2018, 01:57:38 AM »

Just D/L now!
Wonderful job: tons of thanks to all involved  :) :) :)
Logged

Alfie Noakes

  • Art Director
  • member
  • Offline Offline
  • Posts: 1931
Re: B.A.T. V3.4 LINEBACKER
« Reply #27 on: August 20, 2018, 02:54:01 AM »

Rapid download
Flawless installation
Worked straight out of the box........

Many thanks vampire _pilot and the entire BAT team for your continued hard work......

.......now I get to pilot Mr Fokker's new flying vehicle.......what a technological miracle ! :o ........what a time to be alive !  :P 

Cheers

Alfie

PS. By the way.........what's a B 52 ?  :))
Logged
Everything is for the best in the best of all possible worlds

buckdanny

  • member
  • Offline Offline
  • Posts: 14
Re: B.A.T. V3.4 LINEBACKER
« Reply #28 on: August 20, 2018, 02:55:17 AM »

Downloaded the five files without difficulties. Installed without problems (WIN 7, Kaspersky AV). Tested yet. Great work!!!!
Thank you very much for the excellent update.
Logged

Forager

  • member
  • Offline Offline
  • Posts: 307
Re: B.A.T. V3.4 LINEBACKER
« Reply #29 on: August 20, 2018, 06:39:37 AM »

There is always a first time....whatever the problem is, my computer will not even download the installer.
I have tried it with google and firefox and neither one will download it.

The four other packages downloaded without any problem.

Every other package, from the inception of BAT, has installed flawlessly and I wonder what changed in windows or the installer to trigger a refusal to even allow the installer to download?

Logged

whistler

  • Modder
  • member
  • Offline Offline
  • Posts: 1007
Re: B.A.T. V3.4 LINEBACKER
« Reply #30 on: August 20, 2018, 07:13:07 AM »

These are the times we live in Forager, society as well as technology have gone from "Innocent till proven guilty" to "Suspect and a potential threat" ;D

Can't you use the default browser that comes with Windows? Internet Explorer or 'Edge' in Windows 10?
Can't you suspend your antivirus / anti-malware program during 10 mins?
(Desperate?) Can't you download it to your Android Mobile and transfer it to Windows? (Yes! that'll work too!) 8)
Logged
NG-HUD v3.2 | NG-MAP v2.0 | NG-CAM v1.5 (New!): https://www.sas1946.com/main/index.php/board,93.0.html

tartenmuche

  • Supporter
  • member
  • Offline Offline
  • Posts: 401
Re: B.A.T. V3.4 LINEBACKER
« Reply #31 on: August 20, 2018, 09:24:39 AM »

Dear Whistler,
I got it, I trespassed against the various warnings. Audacity pays.
Unfortunately my former WAW3 folder which was a China shop full of mods (I don't remember which one) has been erased.
Perhaps next time one could create a WAW4 folder and just minus the previous WAW3 folder inside BAT.
Anyway congratulations to the crew and
best regards.
Tart
Logged
Intel Core Duo E8400 3GHz, Nvidia GeForce GTX 750 Ti, 2x2 gb DDR2 1066 mHZ

Forager

  • member
  • Offline Offline
  • Posts: 307
Re: B.A.T. V3.4 LINEBACKER
« Reply #32 on: August 20, 2018, 09:35:13 AM »

Thanks whistler, for the suggestions.

I finally figured out how to turn off "check apps and files" in "windows defender security center" and the installer downloaded with no problem and the install went, as usual, just fine.

Everything is up and running, too bad I finally got into Skyrim, it is taking all my time lately.

Logged

SAS~vampire_pilot

  • SAS Team
  • member
  • Online Online
  • Posts: 3156
  • The man of a million fixes
Re: B.A.T. V3.4 LINEBACKER
« Reply #33 on: August 20, 2018, 09:35:47 AM »

Quote
my former WAW3 folder which was a China shop full of mods (I don't remember which one) has been erased.
This is a necessary regular procedure since 3.1 and mentioned in the handbook.

I added an additional warning.
Logged

EHood

  • Supporter
  • member
  • Offline Offline
  • Posts: 406
Re: B.A.T. V3.4 LINEBACKER
« Reply #34 on: August 20, 2018, 10:05:47 AM »

I'm afraid that after trying some of the abovementioned solutions, I still get this every time I try to run  the Linebacker installer:

        78.6 KB    BATinstall.jpg                  Check                                            Error                                                 


Windows Defender continues to identify the problem as a Trojan: Win32/Fuery.8!cl.

This is the first time I have had any trouble with installing a BAT upgrade. Once again, any advice or assistance would be greatly appreciated.




Logged
Etiam necesso campanum vaccis!

SAS~Storebror

  • Editor
  • member
  • Online Online
  • Posts: 16388
  • Ask me if I care.
    • Friendly Fire isn't.
Re: B.A.T. V3.4 LINEBACKER
« Reply #35 on: August 20, 2018, 10:19:18 AM »

Those who are seeing false positives on our installer can try this alternative version which does not require administrative privileges:
http://www.mediafire.com/file/p3k2l9aokiinq18/BAT_3.4_Linebacker_Install_%2528no_Admin%2529.exe/file

Note¹: The "no Admin" version of the installer only works if you've followed the common recommendation to not install IL-2 within the "C:\Program Files" tree (this includes "C:\Program Files (x86)" or any other folder under UAC restrictions).
Note²: Neither of the installers is infected. Mediafire hosts this file. Mediafire themselves check each and every file for viruses when you upload them. They use Bitdefender + Google Screening information for this, see: https://www.bitdefender.com/news/bitdefender-and-mediafire-announce-oem-partnership-to-offer-advanced-anti-virus-protection-to-millions-2151.html
Note³: You can find the Virus Check report for the original installer here and for the "no Admin" installer here. You can find additional information about McAfee's habit of causing tons of false positives on all kind of NSIS installers here to see that we're neither guilty nor alone.
Note⁴: Keep your browsers and AV software updated. Google knows that the installers are safe. Microsoft Defender knows they are safe. Malwarebytes knows they are safe. Don't trust me? See Virustotal. The only ways to get these programs to trigger false positives are: Run them with vastly outdated database on run them on a PC which itself is infected.

]cheers[
Mike
Logged
Learn. Challenge. Improve. In loving memory of the times when I cared...
Pages: 1 2 [3] 4 5 6 ... 9   Go Up
 

Page created in 0.039 seconds with 25 queries.